mirror of
https://github.com/xemu-project/xemu.git
synced 2025-04-02 11:11:48 -04:00
51ab5f8bd7
Currently meson registers a single test that invokes an entire group of I/O tests, hiding the test granularity from meson. There are various downsides of doing this * You cannot ask 'meson test' to invoke a single I/O test * The meson test timeout can't be applied to the individual tests * Meson only gets a pass/fail for the overall I/O test group not individual tests * If a CI job gets killed by the GitLab timeout, we don't get visibility into how far through the I/O tests execution got. This switches meson to perform test discovery by invoking 'check' in dry-run mode. It then registers one meson test case for each I/O test. Parallel execution remains disabled since the I/O tests do not use self contained execution environments and thus conflict with each other. Signed-off-by: Daniel P. Berrangé <berrange@redhat.com> Reviewed-by: Thomas Huth <thuth@redhat.com> Acked-by: Hanna Czenczek <hreitz@redhat.com> Tested-by: Thomas Huth <thuth@redhat.com> Message-Id: <20230303160727.3977246-8-berrange@redhat.com> Signed-off-by: Alex Bennée <alex.bennee@linaro.org> Message-Id: <20230315174331.2959-25-alex.bennee@linaro.org>
70 lines
1.9 KiB
Meson
70 lines
1.9 KiB
Meson
if not have_tools or targetos == 'windows' or get_option('gprof')
|
|
subdir_done()
|
|
endif
|
|
|
|
foreach cflag: config_host['QEMU_CFLAGS'].split()
|
|
if cflag.startswith('-fsanitize') and \
|
|
not cflag.contains('safe-stack') and not cflag.contains('cfi-icall')
|
|
message('Sanitizers are enabled ==> Disabled the qemu-iotests.')
|
|
subdir_done()
|
|
endif
|
|
endforeach
|
|
|
|
bash = find_program('bash', required: false, version: '>= 4.0')
|
|
if not bash.found()
|
|
message('bash >= v4.0 not available ==> Disabled the qemu-iotests.')
|
|
subdir_done()
|
|
endif
|
|
|
|
qemu_iotests_binaries = [qemu_img, qemu_io, qemu_nbd, qsd]
|
|
qemu_iotests_env = {'PYTHON': python.full_path()}
|
|
qemu_iotests_formats = {
|
|
'qcow2': 'quick',
|
|
'raw': 'slow',
|
|
'qed': 'thorough',
|
|
'vmdk': 'thorough',
|
|
'vpc': 'thorough'
|
|
}
|
|
|
|
foreach k, v : emulators
|
|
if k.startswith('qemu-system-')
|
|
qemu_iotests_binaries += v
|
|
endif
|
|
endforeach
|
|
|
|
qemu_iotests_check_cmd = files('check')
|
|
|
|
foreach format, speed: qemu_iotests_formats
|
|
if speed == 'quick'
|
|
suites = 'block'
|
|
else
|
|
suites = ['block-' + speed, speed]
|
|
endif
|
|
|
|
args = ['-tap', '-' + format]
|
|
if speed == 'quick'
|
|
args += ['-g', 'auto']
|
|
endif
|
|
|
|
rc = run_command(
|
|
[qemu_iotests_check_cmd] + args + ['-n'],
|
|
check: true,
|
|
)
|
|
|
|
foreach item: rc.stdout().strip().split()
|
|
args = ['-tap', '-' + format, item,
|
|
'--source-dir', meson.current_source_dir(),
|
|
'--build-dir', meson.current_build_dir()]
|
|
# Some individual tests take as long as 45 seconds
|
|
# Bump the timeout to 3 minutes for some headroom
|
|
# on slow machines to minimize spurious failures
|
|
test('io-' + format + '-' + item,
|
|
qemu_iotests_check_cmd,
|
|
args: args,
|
|
depends: qemu_iotests_binaries,
|
|
env: qemu_iotests_env,
|
|
protocol: 'tap',
|
|
timeout: 180,
|
|
suite: suites)
|
|
endforeach
|
|
endforeach
|